WPB-28422 reconcile stale local memberships for deleted remote conversations - #5504

-- | Fetching stale remote conversations from two different domains in one
-- request reconciles both independently and only from successful responses.
testReconcileStaleMembershipsMultipleDomains :: (HasCallStack) => App ()
testReconcileStaleMembershipsMultipleDomains = do
  resourcePool <- asks resourcePool
  runCodensity (acquireResources 1 resourcePool) $ \[remoteBackend] ->
    runCodensity (startDynamicBackend remoteBackend mempty) $ \_ -> do
      alice <- randomUser OwnDomain def
      ownerStatic <- randomUser OtherDomain def
      ownerDynamic <- randomUser remoteBackend.berDomain def
      connectTwoUsers ownerStatic alice
      connectTwoUsers ownerDynamic alice
      convStatic <- registerMissingRemoteConversation ownerStatic [alice]
      convDynamic <- registerMissingRemoteConversation ownerDynamic [alice]
      eventually $ do
        assertConversationMembership alice convStatic True
        assertConversationMembership alice convDynamic True

      bindResponse (listConversations alice [convStatic, convDynamic]) $ \resp -> do
        resp.status `shouldMatchInt` 200
        resp.json %. "found" `shouldMatch` ([] :: [Value])
        resp.json %. "failed" `shouldMatch` ([] :: [Value])
        notFound <- resp.json %. "not_found" & asList
        for_ [convStatic, convDynamic] $ \conv -> do
          (notFound :: [Value]) `shouldContain` [conv]

      assertConversationMembership alice convStatic False
      assertConversationMembership alice convDynamic False

-- | Conversations the remote still returns are preserved; only omitted ones
-- are reconciled within the same request.
testReconcileOnlyMissingConversations :: (HasCallStack) => App ()
testReconcileOnlyMissingConversations = do
  alice <- randomUser OwnDomain def
  owner <- randomUser OtherDomain def
  connectTwoUsers owner alice

  alive <-
    postConversation owner (defProteus {qualifiedUsers = [alice]})
      >>= getJSON 201
  aliveQid <- objQidObject alive
  stale <- registerMissingRemoteConversation owner [alice]

  eventually $ do
    assertConversationMembership alice aliveQid True
    assertConversationMembership alice stale True

  bindResponse (listConversations alice [aliveQid, stale]) $ \resp -> do
    resp.status `shouldMatchInt` 200
    resp.json %. "failed" `shouldMatch` ([] :: [Value])
    found <- resp.json %. "found" & asList
    length (found :: [Value]) `shouldMatchInt` 1
    notFound <- resp.json %. "not_found" & asList
    (notFound :: [Value]) `shouldContain` [stale]

  assertConversationMembership alice aliveQid True
  assertConversationMembership alice stale False